在 Linux 中屏蔽文件中的位按位运算

发布于07月08日

我想在Linux中屏蔽文件中的位，如下所示:

 actual : 00-00000000-00000011-00110010-10000000
 expect : 00-00000000-00000001-01101010-00000000
 error  : 00-00000000-00000010-01011000-00000000

在输出中，actual部分应该保持原样，除非error是1，那么actual位应该用X进行掩码

如图所示，error是actual和expected数据的XOR.

输出应如下所示:

output : 00-00000000-000000X1-0X1XX010-10000000

有没有使用SED、AWK等命令来实现这一点的方法？

What is done so far:个

grep 'err' gpbat | sed 's?-??g' | cut -c 11-35 | sed 's?1?X?g' > a1
grep 'act' gpbat | sed 's?-??g' | cut -c 11- > a2

但从这里开始，我不知道如何合并a1和a2

推荐答案

使用多种版本的Awk:

awk '
    /actual/ { split($3,a,"") }
    /error/ { split($3,e,"") }

    END {
        for (i in a)
            c[i] = e[i]==1 ? "X" : a[i]

        for (i = length(c); i>0; --i)
            s = c[i] s

        printf "output : %s\n", s
    }
' gpbat

POSIX指出，空字符串的split的结果是未定义的行为"to allow a proposed future extension that would split up a string into an array of individual characters"，但我个人还没有遇到过没有这样做的版本.YMMV.对于完全的可移植性，@markp-fuso的方法使用substr将是首选.

或稍微更高效(per@markp-fuso):

awk '
    /actual/ { n = split($3,a,"") }
    /error/ { split($3,e,"") }

    END {
        for (i = 1; i<=n; ++i)
            o = (o) ( e[i]==1 ? "X" : a[i] )
        print "output :", o
    }
' gpbat

并且，如果输入的顺序得到保证，则处理可以在读取"错误"行之后停止，因此这END个动作可以与exit一起移动到/error/个动作中，以避免不得不读取文件的其余部分:

awk '
    /actual/ { n = split($3,a,"") }
    /error/ {
        split($3,e,"")
        for (i = 1; i<=n; ++i)
            o = (o) ( e[i]==1 ? "X" : a[i] )
        print "output :", o
        exit
    }
' gpbat