Linux 输出特定字符的所有列号

发布于12月23日

我有一个矩阵(大约10,000 x 10,000)，我想找出包含‘0’的列号.

Matrix(test.txt):

1 1 1 1 1 1 1 1 1 1
1 0 1 1 1 0 1 1 1 1
1 1 1 0 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
3 2 2 3 3 0 3 2 2 2
3 2 1 3 3 0 3 2 2 0
3 2 2 3 3 2 3 2 2 2
1 1 1 1 1 1 1 1 1 1

帖子主题:Re:Колибри

2 4 6 10

我是第一次接触Linuxshell ，在类似的例子中没有找到太多.任何帮助都将不胜感激！！

我只知道如何用代码grep -nw '0' test.txt|cut -f1 -d':'找到行号，也许我可以先转置矩阵(like this)？然后使用上面的代码，对吗？有没有更简单的办法呢？

推荐答案

在每个Unix机器上的任何shell 中使用任何awk:

$ awk '
    /(^| )0( |$)/ {
        for ( i=1; i<=NF; i++ ) {
            if ( $i == 0 ) {
                cols[i]
            }
        }
    }
    END {
        for ( i in cols ) {
            printf "%s%d", sep, i
            sep = OFS
        }
        print ""
    }
' file
2 4 6 10

由于使用in运算符的循环，上面的输出不能保证是数字(或任何其他)顺序，有关详细信息，请参阅https://www.gnu.org/software/gawk/manual/gawk.html#Scanning-an-Array.

如果您需要以递增的数字顺序打印字段号，则将脚本更改为非常缓慢的:

awk '
    /(^| )0( |$)/ {
        for ( i=1; i<=NF; i++ ) {
            if ( $i == 0 ) {
                cols[i]
            }
        }
    }
    END {
        for ( i=1; i<=NF; i++ ) {
            if ( i in cols ) {
                printf "%s%d", sep, i
                sep = OFS
            }
        }
        print ""
    }
' file