Linux 无法分析nasm中的单词

您的两个示例都只包含空格和一个终止零..whitespace_reader将循环通过空格，然后偶然发现它将跳到.fail的终止零.那里的ret指令将使用不平衡堆栈，因为返回地址被您推送的RDI、RSI和RAX寄存器的存在阻止.在您当前的代码中没有快速解决此问题的方法，因为它包含其他问题.

• 因为r12、r13、r14、r15、rbx、rsp和rbp是调用保留寄存器，所以不能保证您的R8和R9寄存器在调用read_char之后仍然有效.
• 当调用.whitespace_checker时，您试图遵循调用约定将第一个参数存储在RDI中，这会使问题复杂化.这.whitespace_checker是您自己的子 routine ，并且无论如何都是在本地使用的，所以只使用rax中已有的参数来调用它是完全可以的.也可以在您认为方便的任何寄存器中返回结果，比如本例中的RDX.
• 由于.whitespace_checker返回一个三态结果{0，1，2}，因此您只需要一条cmp dl, 1指令就可以涵盖所有可能的结果.
• .success中的inc rdi将在缓冲区中留下一个未使用的字节，并可能将新的终止零放在缓冲区之外！

这是我的重写，纳入了以上所有内容:

; IN (rdi,rsi) OUT (rax,rdx)
read_word:
    push rbx                  ; Save call-preserved registers
    push r12
    push r13
    xor  ebx, ebx             ; WordLength = 0
    mov  r12, rdi             ; BufferAddress
    mov  r13, rsi             ; BufferSize

.whitespace_reader:           ; Skip leading whitespace
    call read_char            ; -> RAX
    call .whitespace_checker  ; -> RDX={0,1,2}
    cmp  dl, 1
    jb   .whitespace_reader   ; 0 == Whitespace
    ja   .fail                ; 2 == Terminating zero
                              ; 1 == Normal character
.word_reader:
    inc  rbx
    cmp  rbx, r13
    jnb  .fail 
    mov  [r12], al
    inc  r12
    call read_char            ; -> RAX
    call .whitespace_checker  ; -> RDX={0,1,2}
    cmp  dl, 1
    je   .word_reader         ; 1 == Normal character
.success:
    mov  byte [r12], 0        ; New terminating-zero
    mov  rax, r12             ; WordAddress to RAX
    sub  rax, rbx
    mov  rdx, rbx             ; WordLength to RDX
    jmp  .done

; IN (rax) OUT (rdx)
.whitespace_checker:
    xor  edx, edx             ; 0 == Whitespace
    cmp  al, 32
    je   .ret
    cmp  al, 9
    je   .ret
    cmp  al, 10
    je   .ret
    inc  edx                  ; 1 == Normal character
    test al, al
    jnz  .ret
    inc  edx                  ; 2 == Terminating zero
.ret:
    ret
    
.fail:
    xor  eax, eax
.done:
    pop  r13                  ; Restore call-preserved registers
    pop  r12
    pop  rbx
    ret