我希望找到在col1和col2中具有相同值的行，并获得其不同的第三列
假设我有这样的数据
City,Sunset,Anna
City,Sunset,Anna
City,Sunset,Ben
City,Sunset,Ben
我想要的输出是:
City,Sunset,"Anna,Ben"
到目前为止，我有这个代码
cat file.txt | sed 's/,/|/2' | awk -F"," '{if (!($1 in a)) a[$1] = $2; else a[$1]=a[$1] "," $2 } END { for (key in a) print key, a[key] }' OFS=,
但我只得到了
City,Sunset,Anna,Anna,Ben,Ben
何时输出应为
City,Sunset,"Anna,Ben"
有谁能帮我弄一下这个吗？
使用任何awk:
$ cat tst.awk
BEGIN { FS=OFS="," }
{
key = $1 FS $2
val = $3
}
key != prev {
if ( NR > 1 ) {
print prev, "\"" vals "\""
}
vals = sep = ""
prev = key
delete seen
}
!seen[val]++ {
vals = vals sep val
sep = OFS
}
END {
print prev, "\"" vals "\""
}
$ awk -f tst.awk file
City,Sunset,"Anna,Ben"
如果您在前两个输入字段中有多个不同的值，而不管第三个字段值的顺序如何，这将会起作用.
它将按照值在输入中出现的顺序输出值，并且一次只存储一个密钥对的值，而不是存储整个文件.
例如，给定以下输入:
$ cat file
City,Sunset,Anna
City,Sunset,Ben
City,Sunset,Sue
City,Sunset,Ben
Town,Sunrise,Ben
Town,Sunrise,Phil
它将产生我认为是预期的输出:
$ awk -f tst.awk file
City,Sunset,"Anna,Ben,Sue"
Town,Sunrise,"Ben,Phil"
上面的脚本假定您的输入是按前两个字段的值分组的，如果不是这样，则首先对其运行sort -t, -k1,2.