Arduino - 湿度传感器

在本节中，我们将学习如何将Arduino开发板与不同的传感器接口，我们将讨论以下传感器-

• 湿度传感器(DHT22)
• 温度传感器(LM35)
• 水探测器传感器(简单的水触发器)
• PIR传感器
• 超声波传感器
• GPS

湿度传感器(DHT22)

DHT-22(也称为AM2302)是数字输出，相对湿度和温度传感器。它使用电容式湿度传感器和热敏电阻来测量周围的空气，并在数据引脚上发送数字信号

在此示例中，您将学习如何将此传感器与Arduino UNO一起使用，室温和湿度将被打印到串行监视器上。

链接：https://www.learnfk.comhttps://www.learnfk.com/arduino/arduino-humidity-sensor.html

来源：LearnFk无涯教程网

DHT-22传感器

连接很简单。左边的第一个引脚为3-5V电源，第二个引脚为数据输入引脚，最右边的引脚接地。

技术细节

• 电源-3-5V

• 最大电流-2.5mA

• 湿度-0-100％，准确性2-5％

• 温度-40至80°C，精度为±0.5°C

所需组件

您将需要以下组件-

• 1×Breadboard
• 1×Arduino Uno R3
• 1×DHT22
• 1×10K欧姆电阻

电路图

遵循电路图，并连接面包板上的组件，如下图所示。

Arduino代码

//各种 DHT 湿度/温度传感器的示例测试草图

#include "DHT.h"
#define DHTPIN 2 //我们连接到什么数字引脚
//取消注释您使用的任何类型！
//#define DHTTYPE DHT11 //DHT 11
#define DHTTYPE DHT22 //DHT 22 (AM2302), AM2321
//#define DHTTYPE DHT21 //DHT 21 (AM2301)
//将传感器的引脚 1（左侧）连接到 +5V
//NOTE: 如果使用具有 3.3V 逻辑的板，如 Arduino Due 连接引脚 1
//改为 3.3V 而不是 5V！
//将传感器的引脚 2 连接到您的 DHTPIN 是什么
//将传感器的引脚 4（右侧）连接到 GROUND
//将 10K 电阻从引脚 2（数据）连接到传感器的引脚 1（电源）
//初始化 DHT 传感器。
//请注意，此库的旧版本采用可选的第三个参数
//调整更快的处理器的时间。不再需要此参数
//因为当前的 DHT 读取算法会自行调整以处理更快的 procs。
DHT dht(DHTPIN, DHTTYPE);

void setup() {
   Serial.begin(9600);
   Serial.println("DHTxx test!");
   dht.begin();
}

void loop() {
   delay(2000); //在测量之间等待几秒钟
   float h=dht.readHumidity();
   //读取温度或湿度大约需要 250 毫秒！
   float t=dht.readTemperature();
   //将温度读取为摄氏度（默认值）
   float f=dht.readTemperature(true);
   //将温度读取为华氏温度 (isFahrenheit=true)
   //检查是否有任何读取失败并提前退出（重试）。
   if (isnan(h) || isnan(t) || isnan(f)) {
      Serial.println("Failed to read from DHT sensor!");
      return;
   }
   
   //以华氏计算热量指数（默认）
   float hif=dht.computeHeatIndex(f, h);
   //以摄氏度计算热量指数 (isFahreheit=false)
   float hic=dht.computeHeatIndex(t, h, false);
   Serial.print ("Humidity: ");
   Serial.print (h);
   Serial.print (" %\t");
   Serial.print ("Temperature: ");
   Serial.print (t);
   Serial.print (" *C ");
   Serial.print (f);
   Serial.print (" *F\t");
   Serial.print ("Heat index: ");
   Serial.print (hic);
   Serial.print (" *C ");
   Serial.print (hif);
   Serial.println (" *F");
}

注意代码

DHT22传感器具有四个端子(V _cc ，DATA，NC，GND)，这些端子按如下方式连接至电路板:

• DATA引脚连接到Arduino引脚编号2
• V _cc 引脚连接到5伏的Arduino板
• GND引脚连接到Arduino板的地面
• 我们需要在DATA和V _cc 引脚之间连接10k欧姆电阻(上拉电阻)

硬件连接完成后，您需要如前所述将DHT22库添加到Arduino库文件中。

输出结果

您将在串口监视器上看到温度和湿度显示，该显示每2秒更新一次。